It is always a good idea to revisit existing GAMS code and see if we can improve it. Here is an example of an actual model.
The problem is that we want to set up a mapping set between two sets based on the first two characters. If they are the same, the pair should be added to the mapping. The old code looked like:
|
sets
r 'regions' /
AP 'Appalachia'
CB 'Corn Belt'
LA 'Lake States'
/
s 'subregions' /
APN0501
APN0502
APN0504
CBL0704
CBM0404
LAM0404
LAM0406
/
rs(r,s) 'mapping
regions<->subregions'
;
* old code:
PARAMETER value;
LOOP(R, value('1',R) =
100*ord( R.tl,1) + ord(
R.tl,2); );
LOOP(S, value('2',S) =
100*ord( S.tl,1) + ord(
S.tl,2); );
RS(R,S)$(value('1',R) = value('2',S)) =
YES;
display value;
display rs;
|
To verify this indeed generates the correct result for set rs, we look at the output:
---- 27 PARAMETER value
AP CB LA APN0501 APN0502 APN0504 CBL0704 CBM0404 LAM0404
1 6580.000 6766.000 7665.000
2 6580.000 6580.000 6580.000 6766.000 6766.000 7665.000
+ LAM0406
2 7665.000
---- 28 SET rs mapping regions<->subregions
APN0501 APN0502 APN0504 CBL0704 CBM0404 LAM0404 LAM0406
AP YES YES YES
CB YES YES
LA YES YES
The set rs is obviously correctly populated. The auxiliary parameter value contains the ASCII values: e.g. AP has value 6580 as the decimal ASCII codes for A and P are 65 and 80.
Notes:
- The function ord(string, pos) returns the ASCII value of the character at position pos of the string.
- The suffix .TL is the text string of the set element (internally GAMS does not work with the strings but rather an integer id for each set element; here we make it explicit we want the string).
- The loops are not really needed. We could have used:
value('1',R) = 100*ord( R.tl,1) + ord( R.tl,2);
value('2',S) = 100*ord( S.tl,1) + ord( S.tl,2); - The mapping set is a very powerful concept in GAMS. It is somewhat like a dict in Python, except it is not one way. It can map from r to s but also from s to r.
We can simplify the code to just:
|
* new
code:
* compare first two characters in r and s
rs(r,s) = ord(r.tl,1)=ord(s.tl,1)
and ord(r.tl,2)=ord(s.tl,2);
display rs;
|
This gives the same result:
---- 22 SET rs mapping regions<->subregions
APN0501 APN0502 APN0504 CBL0704 CBM0404 LAM0404 LAM0406
AP YES YES YES
CB YES YES
LA YES YES
Notes:
- No need for the auxiliary parameter value.
- No loops.
- We could add a check that we have no unmapped subregions. E.g. by:
abort$(card(rs)<>card(s)) "There
are unmapped subregions"; - This will also catch cases where the casing does not match.
- Critical note: GAMS has very poor support for strings. This should have been rectified a long time ago. There is no excuse for this deficiency.
Conclusion
It is always worthwhile to revisit existing models and clean them up. During development, especially when under time pressure, we often are happy once our code works. As the lifetime of models can be surprisingly long, and thus new generations of users and modelers start working with old models, it is a good idea to do a cleanup round to make the code as readable as possible.
